批处理病毒清理助手VirusCleaner V1.3.2 bat版

批处理病毒清理助手：可查杀常见U盘病毒、同名文件夹病毒、随机名称病毒。恢复被隐藏文件夹，修复映像劫持。一键结束非系统进程、清理系统垃圾、自启动项、任务计划。
主要升级内容：
兼容WindowsXP和Windows7。W7与XP有许多区别，进行了逐一修正。
升级了清理同名文件夹病毒功能，发现同名EXE文件进行隔离而非清除。
改善了配置和界面等功能。整体上使得功能完善，但程序变得复杂了。
修复了一些BUG，如一键清理非系统进程、启动项等。

有两个问题需要强调：
因为涉及到修改注册表等敏感操作，可能会被360等杀毒软件拦截，请允许放行。
设置好的有些内容可能只是普通文件，但为病毒所利用，请根据自己情况判断。
改善SVCHOST.exe内存使用量高的判断，对彻底杀毒十分必要，但也可能导致系统异常，甚至蓝屏死机！重启即可。

为什么需要批处理病毒清理助手VirusCleaner？
有些U盘病毒并不能为360等杀毒软件发现和查杀，比如同名文件夹病毒，但它却困扰着许多人。而本程序对同名文件夹病毒和随机名称病毒具有很好的发现和查杀功能。——这个可不是吹牛！
本程序原本是本人杀毒专用辅助工具，因结合同名文件夹病毒专杀等功能，经过多方测试成功有效，一来演示杀毒模板的作用，二来方便传播杀毒方法。
本程序核心功能：一是定制杀毒，二是提高系统运行速度。为许多菜鸟带来福音。

批处理杀毒模板，最初版本，仅供参考！

[code]
@echo off&title VirusCleaner V1.0
:start
cls
echo 请在批处理编辑状态下修改杀毒设置。
echo 并按任意键开始杀毒！
pause>nul
set processname=IEXPLORE.EXE SuCH0ST.EXE down.EXE boot.EXE systen.EXE expl0rer.EXE fun.EXE
::结束进程【将你获得的病毒进程名称加入到以上设置，并以空格隔开】
set filename=a.txt b.txt c.txt d.txt mailbody.txt ok.txt out.txt output.txt mail3.vbe Attusb.dll autousb.bat WIN.bat dd.bat SuCH0ST.exe down.exe boot.exe 1.RMVB fun.exe
::删除文件【将你从根目录 %SYSTEMROOT%\system32 中获得的病毒文件名加入到以上设置，并以空格隔开】
set findfilename=autorun.inf lpk.dll SuCH0ST.EXE down.EXE boot.EXE systen.EXE expl0rer.EXE fun.EXE
::全盘搜索并删除文件【将病毒文件名加入到以上设置，并以空格隔开】
set servicename=DNSSystem
::停用服务项【将病毒服务项名加入到以上设置，并以空格隔开】
::-----------------------------------------------------------------------------
echo ——杀毒进行中 . . .
echo 结束病毒进程 . . .
taskkill /f /im explorer.exe
for %%a in (%processname%) do taskkill /f /t /im %%a
start explorer.exe
echo ——清除指定病毒文件 . . .
for %%a in (%filename%) do if exist %SYSTEMROOT%\system32\%%a (
    ATTRIB %SYSTEMROOT%\system32\%%a -s -h -a -r
    del /f /s /a /q %SYSTEMROOT%\system32\%%a
)
echo ——恢复D盘被隐藏的文件夹 . . .
setlocal EnableDelayedExpansion
call :hs d:\
echo ——恢复移动盘被隐藏的文件夹 . . .
for /f "skip=1" %%i in ('wmic logicaldisk where "drivetype='2'" get caption') do (if exist %%i\ call :hs %%i\&call :rec %%i\)
echo ——停止病毒服务项 . . .
for %%a in (%servicename%) do (
    sc stop %%a
    sc config %%a start= disabled
)
echo ——全盘清除指定病毒文件 . . .
for %%a in (%findfilename%) do (
    for /f "skip=1" %%i in ('wmic logicaldisk where "drivetype='3'" get caption') do for /f "tokens=*" %%x in ('dir /b /s /a %%i\%%a') do if exist "%%~x" (
        ATTRIB -s -h -a -r "%%~x"
        del /f /s /a /q "%%~x"
    )
)
echo ——清除所有计划任务 . . .
at /delete /yes
SCHTASKS /Delete /TN * /F
del /f /q /a C:\WINDOWS\Tasks
::for /f "tokens=*" %%a in ('dir /s /b /a %SYSTEMROOT%\Tasks\*.job') do if exist "%%~a" del /f /s /a /q "%%~a"

echo ——清除任何随机自启动 . . .
reg  delete HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run /v fun /f
echo;&echo ——杀毒结束！按任意键返回！&echo;
pause>nul&goto start

:hs 恢复被隐藏的文件夹
for /f "delims=" %%q in ('dir %1 /a:d /b') do (
    if exist "%1%%~q" ATTRIB  "%1%%~q" -s -h -a -r
    if exist "%1%%~q.exe" del /f /s /a /q "%1%%~q.exe"
)
goto :eof
:rec 清理常见U盘病毒
for /f "delims=" %%q in ('dir /a /b  %1autorun.inf,%1recycle.*') do if exist "%1%%~q" (
    ATTRIB "%1%%~q" -s -h -a -r
    del /f /s /a /q "%1%%~q"
)
goto :eof
配合《一键清理三剑客》使用可能效果更好！~
[/code]