全盘禁止运行指定程序的bat版下载-脚本之家

热门排行

简介

熊猫等专杀一大堆，这个东东有什么特色呢？这是本人摸索了几天编写的一个批处理文件，网上是绝对找不到的，其主要原理是在注册表中限制熊猫、威金、金猪等主程序的运行，目前阻止：FuckJacks.exe、spcolsv.exe、spoclsv.exe、sppoolsv.exe、suchost.exe、Logo1_.exe、0Sy.exe、1Sy.exe、2Sy.exe、3Sy.exe、4Sy.exe、5Sy.exe、6Sy.exe、EXP10RER.com、EXP10RER.exe、EXPl0RER.exe、vipbkv.exe、rose.exe、sxs.exe......等病毒文件的运行。
运行这个批处理后，这些病毒可执行文件将不能运行。就算已感染了病毒，且病毒正在运行，那也没关系，运行这个批处理后，重启电脑，这些病毒程序将不能运行。
我是不是在吹牛？试试就知道！

这个批处理的内容如下：我提供的目前来说应是一种新的免疫方法，注意不要把系统进程比如LSASS.EXE等加进去，否则重启电脑后连系统都进不了。这个批处理不再更新，由namejm朋友精简了代码，核心代码就只有两条 for 语句，可以适应系统分区不在C盘的情况。请和附件中的 list.ini 配套使用，有需要的朋友可自行更新，把病毒的可执行程序加进list.ini去就行了：
在此感谢namejm朋友！

[code]
@echo off
:: 出处：//bbs.wuyou.com/viewthread.php?tid=94384
mode con cols=84 lines=21
title 注册表限制威金、熊猫、金猪病毒运行
color 4f
cls
echo.
echo.
echo                     注册表限制威金、熊猫、金猪病毒的运行 for /XP
echo          -----------------------------------------------------------------
echo.
echo              此批处理可以限制2007年2月9日前的威金、熊猫、金猪病毒的运行。
echo          比如运行一个SETUP.EXE的熊猫病毒，该病毒会生成c:\WINDOWS\SYTEM32\
echo          FuckJacks.exe，由于我限制了FuckJacks.exe的运行，所以不管怎么双击
echo          运行SETUP.EXE，都不能成功运行病毒c:\WINDOWS\SYTEM32\FuckJacks.exe
echo          因而病毒也就起不了作用，等于废了。
echo.
echo                                                     6618   2007年2月10日
echo                                               Modified by JM 07年2月11日
echo.
echo          [F] 按 F 键进行注册表限制
echo          [U] 按 U 键解除注册表限制
echo          [Q] 按其他任意键退出
echo          -----------------------------------------------------------------
echo.

set route=HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options
SET Choice=
SET /P Choice= 请选择要进行的操作：
IF /I '%Choice:~0,1%'=='f' GOTO fix
IF /I '%Choice:~0,1%'=='u' GOTO unfix
exit

:fix
echo.
echo                           正在进行免疫操作，请稍侯...
:: 下一句中的 "全盘禁止运行%%i" 可以替换成任意的字符，都能起到全盘禁止运行指定exe的效果
for /f %%i in (list.ini) do (
    reg add "%route%\%%i" /v Debugger /t REG_SZ /d 全盘禁止运行%%i /f >nul 2>nul
)
cls
echo.&echo.&echo.&echo.&echo.
echo                 已在注册表中限制威金、熊猫、金猪病毒的运行。
echo.
echo                 如果已中了此类病毒，运行这个批处理后，请
echo.
echo                 重启电脑进行杀毒。
echo.
echo                        感谢使用，按任意键退出...
pause>nul
exit

:unfix
echo.
echo                           正在解除限制，请稍侯...
for /f %%i in (list.ini) do reg delete "%route%\%%i" /f >nul 2>nul
cls
echo.&echo.&echo.&echo.&echo.&echo.&echo.
echo                 已解除注册表中对熊猫、威金、金猪病毒的制限。
echo.
echo                  感谢使用，按任意键退出...
pause>nul
[/code]