DOS/BAT

关注公众号 jb51net

关闭
首页 > 脚本专栏 > DOS/BAT > bat前一天日期

bat脚本得到前一天的日期的代码

作者：mdxy

这篇文章主要介绍了bat脚本得到前一天的日期的代码,脚本之家小编对比了网上很多代码,每个代码都经过测试,修复了部分错误,需要的朋友可以参考一下

最近需要获取当前日期的前一天，今天日期为2024-5-17 12:54:24

但部分代码只是不是所有机器通用。有些机器的%date%的格式本身就是2024-5-17，有的机器是2024/5/17 所以建议先稍微改一下bat中的delims=-，这个-就是分隔符，大家可以根据自己的需求修改即可。此代码在2019 data center中测试通过。

实现代码一

::判断当前日期的前一天
::首先直接把天数减1天
::如果出来的是0天就把月减1天，天数是当月的最后一天。
::如果出来的是0月就把年减1年，月数是当年的最后一月。
@echo off
set yyyy=%date:~2,2%
set mm=%date:~5,2%
set dd=%date:~8,2%
set /a od=%dd%-1
if %od%==0 call :dd0
if %mm%==0 call :mm0
set yestaday=%yyyy%%mm%%od%
echo %yestaday%
pause
:dd0
set /a mm=%mm%-1
for %%a in (1 3 5 7 8 10 12)do set %%add=31
set /a pddd=%yyyy%*10/4
set pd2d=%pddd:~-1,1%
set 2dd=28
if %pd2d%==0 set 2dd=29
for %%b in (4 6 9 11)do set %%bdd=30
set od=%%mm%dd%
goto :eof
:mm0
set /a yyyy=%yyyy%-1
set mm=12 && set od=31
goto :eof

效果图

实现代码二

计算N天前的日期的bat脚本

@echo off
rem 计算指定天数之前的日期
set DaysAgo=1
rem 假设系统日期的格式为yyyy-mm-dd
call :DateToDays %date:~0,4% %date:~5,2% %date:~8,2% PassDays
set /a PassDays-=%DaysAgo%
call :DaysToDate %PassDays% DstYear DstMonth DstDay
set DstDate=%DstYear%-%DstMonth%-%DstDay%
echo %DaysAgo%天的日期是%DstDate%
pause
goto :eof

:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF

:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF

效果图

实现代码三

@echo off
echo wscript.echo dateadd("d",-1,now())>x.vbs
for /f %%i in ('cscript /nologo x.vbs') do set d=%%i
del x.vbs
echo %d%
pause

代码输出格式化需要自己额外加。不如上面两个可以自定义格式

例如:240517 或者 20240517

实现代码四

小编用了一点时间修复原来代码的分割符号//或者，或者-的问题

echo off
echo wscript.echo dateadd("d",-1,now())>vbs.vbs
for /f %%a in ('cscript /nologo vbs.vbs') do del vbs.vbs&&set yyyymmdd=%%a
for /f "tokens=1,2,3* delims=-" %%i in ('echo %yyyymmdd%') do set yyyy=%%i&set mm=%%j&set dd=%%k
if %mm% LSS 9 set mm=0%mm%
if %dd% LSS 9 set dd=0%dd%
set yesterday=%yyyy%-%mm%-%dd%
echo 昨天是：%yesterday%
echo 请按任意键退出
pause>nul

这段代码比较好看，也比较精简，大家使用过程中有什么问题可以交流。

实现代码五

@echo off
set "today=%date%"
set "year=%today:~0,4%"
set "month=%today:~5,2%"
set "day=%today:~8,2%"
set /A "day=day-1"
if %day%==0 (
    set /A "month=month-1"
    if %month%==0 (
        set /A "year=year-1"
        set "month=12"
    )
    if %month%==1 set "month=01"
    if %month%==2 set "month=02"
    if %month%==3 set "month=03"
    if %month%==4 set "month=04"
    if %month%==5 set "month=05"
    if %month%==6 set "month=06"
    if %month%==7 set "month=07"
    if %month%==8 set "month=08"
    if %month%==9 set "month=09"
    set /A "last_day=30+(month+month/8)%%2"
    set "day=%last_day%"
)
if %day%==1 set "day=01"
if %day%==2 set "day=02"
if %day%==3 set "day=03"
if %day%==4 set "day=04"
if %day%==5 set "day=05"
if %day%==6 set "day=06"
if %day%==7 set "day=07"
if %day%==8 set "day=08"
if %day%==9 set "day=09"
echo %year%-%month%-%day%
pause

实现代码六

@echo off
setlocal enabledelayedexpansion
set "timestamp=%date%"
set "year=%timestamp:~0,4%"
set "month=%timestamp:~5,2%"
set "day=%timestamp:~8,2%"
set /A "day=day-1"
if %day%==0 (
    set /A "month=month-1"
    if !month!==00 (
        set /A "year=year-1"
        set "month=12"
    )
    for %%m in (01 02 03 04 05 06 07 08 09 10 11 12) do (
        if !month!==%%m (
            if "!month!" lss 10 (
                set "month=0!month!"
            )
        )
    )
    set /A "last_day=30+(month+month/8)%%2"
    set "day=!last_day!"
)
for %%d in (01 02 03 04 05 06 07 08 09) do (
    if !day!==%%d (
        set "day=0!day!"
    )
)
echo %year%-%month%-%day%
pause

Windows自动备份（每天、每月最后一天、每个周日），自动清除备份命令

备份效果：保留最新7天的网站备份、最新4个周末的网站备份，每个月底的备份永久保留。

使用的WinRAR做文件压缩，请自行安装并注意命令中WinRAR的路劲、备份文件夹、存放路劲、3个异地存放路劲，根据应用需要调整。

将该BAT文件配置到Windows“任务计划程序”中，频率为每天固定时间运行（比如23点），即可实现自动备份。

下面是关于备份命令的几点简单说明（详细参数或用法请自行查询详细资料了解）：

命令中::代表注释
set后定义的是变量名及值
%%之间加变量名，是取变量的值，%date:~0,4%指的是取系统时间中的前四位即年份数字
WinRAR压缩，排除了带.log的文件
xcopy即复制命令，/d指比较目标和原目录，目标目录为空则复制所有，否则只复制更新过的，/y指禁止提示确认要覆盖已存在的目标文件
FORFILES命令，/P指定Path ，表明要从哪里开始搜索；/M指按照条件搜索文件，默认是*.* ；/C指在每个文件上运行指定的Command 。带有空格的命令字符串必须用引号括起来。默认的Command 是"cmd /c echo @file"；/D指选择日期大于或等于(+ )（或者小于或等于(- )）指定日期的文件，不带时间参数则代表与当前日期比较
代码中判断是否是周日，使用的是“日”这个字，考虑的是中文环境，英文环境请自行修改
闰年判断已经调整为标准的闰年判断条件（条件1：公历年份是4的倍数，且不是100的倍数；条件2：公历年份是整百数的，必须是400的倍数），%%代表取余
>>用来向文件中写日志
新补充：set /a m=%date:~5,2%*1 这一行有BUG，8月份带出的数字是08，默认识别为八进制，且为不识别的八进制数字。错误信息：无效数字。数字常数只能是十进制(17)，十六位进制(0x11)或 八进制(021)。调整为：set  m=%date:~5,2% 即可。因为后面已经有if %m:~0,1%==0 set /a m=%m:~1,1%*1 这句处理0开头的情况。

@echo off
::年月日字符串
set str_date=%date:~0,4%%date:~5,2%%date:~8,2%
::星期几
set str_week_val=%date:~-1%
::本地要备份的文件夹路径
set str_webpath_local=D:\wwwroot
::本地备份文件存放路径
set str_path_local=D:\web_bak
::网站压缩包名称前缀
set str_rar_name=MH_WEB
::异地 备份路径
set str_path_day=z:\最新7天网站备份
::异地 备份路径
set str_path_weekend=z:\最新4个周末的网站备份
::异地 备份路径
set str_path_month=z:\每个月底的网站备份
::取两位月份数字
set m=%date:~5,2%
::第一位为0则只取个位数
if %m:~0,1%==0 set /a m=%m:~1,1%*1
::取四位年份数字（这个命令用不到5位数那年吧）
set /a x=%date:~0,4%
::闰年判断条件1 %%代表取余
set /a y=%x%*1%%4
set /a y2=%x%*1%%100
::闰年判断条件2 %%代表取余
set /a y3=%x%*1%%400
::默认2月份只有28天
set ld=28
::满足闰年条件1
if %y%==0  (
    if %y2% NEQ  0  set ld=29
)
::满足闰年条件2
if %y3%==0  set ld=29
for %%i in (1 3 5 7 8 10 12)do (if %m%==%%i set /a ld=31)
for %%i in (4 6 9 11)do (if %m%==%%i set /a ld=30)
::echo  日期：%ld%
::pause
::当月月底的年月日字符串
set str_monthend_val=%date:~0,4%%date:~5,2%%ld%%
c:
cd C:\Program Files\WinRAR\
echo %time%开始压缩 >>%str_path_local%\%str_date%_log.bak
rar a -u -x*.log* %str_path_local%\%str_rar_name%%str_date%.rar %str_webpath_local%
echo %time%结束压缩 >>%str_path_local%\%str_date%_log.bak
echo. >>%str_path_local%\%str_date%_log.bak
echo %time%开始复制 >>%str_path_local%\%str_date%_log.bak
if "%str_date%"=="%str_monthend_val%" (
	xcopy %str_path_local%\%str_rar_name%%str_date%.rar %str_path_month% /d/y
) else (
if "%str_week_val%"=="日" ( 
	xcopy %str_path_local%\%str_rar_name%%str_date%.rar %str_path_weekend% /d/y
	::删除4周前的rar文件
	FORFILES /P %str_path_weekend%  /M *.rar /D -22 /C "cmd /c echo %time% deleting..@file.. &del @file">>%str_path_local%\%str_date%_del.bak
) else (
	xcopy %str_path_local%\%str_rar_name%%str_date%.rar %str_path_day% /d/y
	::删除7天前的rar文件
	FORFILES /P %str_path_day%  /M *.rar /D -7 /C "cmd /c echo %time% deleting..@file.. &del @file">>%str_path_local%\%str_date%_del.bak
)
)
echo %time%结束复制 >>%str_path_local%\%str_date%_log.bak
echo. >>%str_path_local%\%str_date%_log.bak
::删除本地1天前的rar文件
FORFILES /P %str_path_local%  /M *.rar /D -1 /C "cmd /c echo %time% deleting..@file.. &del @file">>%str_path_local%\%str_date%_del.bak
::删除本地7天前的bak记录文件
FORFILES /P %str_path_local%  /M *.bak /D -7 /C "cmd /c echo %time% deleting..@file.. &del @file">>%str_path_local%\%str_date%_del.bak

到此这篇关于bat脚本得到前一天的日期的代码的文章就介绍到这了,更多相关bat前一天日期内容请搜索脚本之家以前的文章或继续浏览下面的相关文章希望大家以后多多支持脚本之家！

您可能感兴趣的文章:
阅读全文