易语言获取网页端的好友管理页面信息导出QQ好友的代码

.版本 2
.全局变量 Cookie_Overall, 文本型
.全局变量 BKN_Overall, 文本型

.版本 2
.程序集 窗口程序集_窗口1
.子程序 _超文本浏览框1_跳转完毕
.局部变量 Cookie, 文本型
.局部变量 Uin, 文本型
.局部变量 Skey, 文本型
Cookie ＝ 网页_取Cookie (“qun.qq.com”)
.如果真 (寻找文本 (Cookie, “p_skey”, , 假) ≠ -1)
  Uin ＝ 文本_取出中间文本 (Cookie, “p_uin=o”, “;”)
  Skey ＝ 文本_取出中间文本 (Cookie, “skey=”, “;”)
  BKN_Overall ＝ Get_BKN (Skey)
  Cookie_Overall ＝ Cookie
  _启动窗口.按钮_快速登录.标题 ＝ “已登录”
  _启动窗口.标签_QQ号码.标题 ＝ “QQ号码：” ＋ 到文本 (到整数 (Uin))
  _启动窗口.图片框1.图片 ＝ Get_QQHEAD (Uin)
  初始化 ()
  销毁 ()
.如果真结束

.版本 2
.程序集 程序集1
.子程序 Get_BKN, 文本型
.参数 Skey, 文本型
.局部变量 基值, 整数型
.局部变量 计数, 整数型
.局部变量 长度, 整数型
.局部变量 结果, 整数型
基值 ＝ 5381
计数 ＝ 0
长度 ＝ 取文本长度 (Skey)
.判断循环首 (计数 ＜ 长度)
  基值 ＝ 基值 ＋ 左移 (基值, 5) ＋ 取代码 (Skey, 计数 ＋ 1)
  计数 ＝ 计数 ＋ 1
.判断循环尾 ()
结果 ＝ 位与 (基值, 2147483647)
返回 (到文本 (结果))
.子程序 Get_QQHEAD, 字节集
.参数 Uin, 文本型
.局部变量 Url, 文本型
Url ＝ “http://q4.qlogo.cn/g?b=qq&nk=” ＋ Uin ＋ “&s=140”
返回 (网页_访问 (Url))
.子程序 Get_Friend_List, 文本型
.参数 Cookie, 文本型
.参数 BKN, 文本型
.局部变量 Url, 文本型
.局部变量 Post, 文本型
.局部变量 Ret, 文本型
Url ＝ “http://qun.qq.com/cgi-bin/qun_mgr/get_friend_list”
Post ＝ “bkn=” ＋ BKN
Ret ＝ 编码_Utf8到Ansi (网页_访问 (Url, 1, Post, Cookie))
返回 (Ret)

.版本 2
.支持库 iext
.支持库 eExcel2000
.程序集 窗口程序集_启动窗口
.子程序 __启动窗口_创建完毕
图片框1.图片 ＝ #QQ头像
.子程序 初始化
.局部变量 Ret, 文本型
.局部变量 Json, 类_json
.局部变量 i1, 整数型
.局部变量 i2, 整数型
.局部变量 Gname, 文本型
.局部变量 Name, 文本型
.局部变量 Uin, 文本型
.局部变量 s, 整数型
超级列表框1.全部删除 ()
Ret ＝ Get_Friend_List (Cookie_Overall, BKN_Overall)
Json.解析 (Ret)
.计次循环首 (15, i1)
  Gname ＝ Json.取通用属性 (“result[” ＋ 到文本 (i1 － 1) ＋ “].gname”)
  .如果真 (Gname ＝ “”)
    Gname ＝ “我的好友”
  .如果真结束
  .计次循环首 (Json.成员数 (“result[” ＋ 到文本 (i1 － 1) ＋ “].mems”), i2)
    Name ＝ Json.取通用属性 (“result[” ＋ 到文本 (i1 － 1) ＋ “].mems[” ＋ 到文本 (i2 － 1) ＋ “].name”)
    Uin ＝ Json.取通用属性 (“result[” ＋ 到文本 (i1 － 1) ＋ “].mems[” ＋ 到文本 (i2 － 1) ＋ “].uin”)
    s ＝ 超级列表框1.插入表项 (, , , , , )
    超级列表框1.置标题 (s, 0, 到文本 (s ＋ 1))
    超级列表框1.置标题 (s, 1, Uin)
    超级列表框1.置标题 (s, 2, Name)
    超级列表框1.置标题 (s, 3, Gname)
  .计次循环尾 ()
.计次循环尾 ()
.子程序 _按钮_快速登录_被单击
载入 (窗口1, , 假)
.子程序 _按钮_注销登录_被单击
网页_清除Cookie (“qun.qq.com”)
Cookie_Overall ＝ “”
BKN_Overall ＝ “”
按钮_快速登录.标题 ＝ “快速登录”
标签_QQ号码.标题 ＝ “QQ号码：未登录”
图片框1.图片 ＝ #QQ头像
超级列表框1.全部删除 ()
信息框 (“注销登录成功”, 0, )
.子程序 _按钮_全部选中_被单击
.局部变量 i, 整数型
.计次循环首 (超级列表框1.取表项数 (), i)
  超级列表框1.置状态图片 (i － 1, 1)
.计次循环尾 ()
.子程序 _按钮_全部不选_被单击
.局部变量 i, 整数型
.计次循环首 (超级列表框1.取表项数 (), i)
  超级列表框1.置状态图片 (i － 1, -1)
.计次循环尾 ()
.子程序 _按钮_导出全部_被单击
通用对话框1.初始目录 ＝ 取运行目录 ()
通用对话框1.类型 ＝ 1
通用对话框1.默认文件后缀 ＝ “.xls”
通用对话框1.过滤器 ＝ “Excel文件（*.xls）|*.xls|文本文件（*.txt）|*.txt”
通用对话框1.文件名 ＝ 文本_取右边 (标签_QQ号码.标题, “QQ号码：”)
.如果真 (通用对话框1.打开 ())
  .如果真 (倒找文本 (通用对话框1.文件名, “.xls”, , 假) ≠ -1)
    导出Excel (通用对话框1.文件名, 真)
  .如果真结束
  .如果真 (倒找文本 (通用对话框1.文件名, “.txt”, , 假) ≠ -1)
    导出Txt (通用对话框1.文件名, 真)
  .如果真结束
  信息框 (“保存成功”, 0, )
.如果真结束
.子程序 _按钮_导出选中_被单击
通用对话框1.初始目录 ＝ 取运行目录 ()
通用对话框1.类型 ＝ 1
通用对话框1.默认文件后缀 ＝ “.xls”
通用对话框1.过滤器 ＝ “Excel文件（*.xls）|*.xls|文本文件（*.txt）|*.txt”
通用对话框1.文件名 ＝ 文本_取右边 (标签_QQ号码.标题, “QQ号码：”)
.如果真 (通用对话框1.打开 ())
  .如果真 (倒找文本 (通用对话框1.文件名, “.xls”, , 假) ≠ -1)
    导出Excel (通用对话框1.文件名, 假)
  .如果真结束
  .如果真 (倒找文本 (通用对话框1.文件名, “.txt”, , 假) ≠ -1)
    导出Txt (通用对话框1.文件名, 假)
  .如果真结束
  信息框 (“保存成功”, 0, )
.如果真结束
.子程序 导出Txt
.参数 文件名, 文本型
.参数 全部, 逻辑型
.局部变量 i, 整数型
.局部变量 Uin, 文本型
.局部变量 Name, 文本型
.局部变量 Gname, 文本型
.局部变量 Str, 文本型
.如果真 (全部 ＝ 真)
  .计次循环首 (超级列表框1.取表项数 (), i)
    Uin ＝ 超级列表框1.取标题 (i － 1, 1)
    Name ＝ 超级列表框1.取标题 (i － 1, 2)
    Gname ＝ 超级列表框1.取标题 (i － 1, 3)
    Str ＝ Str ＋ Uin ＋ “----” ＋ Name ＋ “----” ＋ Gname ＋ #换行符
  .计次循环尾 ()
.如果真结束
.如果真 (全部 ＝ 假)
  .计次循环首 (超级列表框1.取表项数 (), i)
    .如果真 (超级列表框1.取当前状态图片 (i － 1) ＝ 1)
      Uin ＝ 超级列表框1.取标题 (i － 1, 1)
      Name ＝ 超级列表框1.取标题 (i － 1, 2)
      Str ＝ Str ＋ Uin ＋ “----” ＋ Name ＋ “----” ＋ Gname ＋ #换行符
    .如果真结束
  .计次循环尾 ()
.如果真结束
写到文件 (文件名, 到字节集 (Str))
.子程序 导出Excel
.参数 文件名, 文本型
.参数 全部, 逻辑型
.局部变量 Data_Head, 文本型, , "0"
.局部变量 i1, 整数型
.局部变量 i2
Excel程序1.创建 ()
Excel工作簿1.置程序 (Excel程序1)
Excel工作簿1.激活工作簿 ()
Excel工作簿1.表格序号 ＝ 1
Data_Head ＝ { “QQ号码”, “QQ昵称”, “QQ分组” }
.计次循环首 (取数组成员数 (Data_Head), i1)
  Excel工作簿1.首单元格 ＝ 字符 (97 ＋ i1 － 1) ＋ 到文本 (1)
  Excel工作簿1.尾单元格 ＝ 字符 (97 ＋ i1 － 1) ＋ 到文本 (1)
  Excel工作簿1.内容格式 ＝ “@”
  Excel工作簿1.内容 ＝ Data_Head [i1]
  Excel工作簿1.列宽 ＝ 20
.计次循环尾 ()
.如果真 (全部 ＝ 真)
  .计次循环首 (超级列表框1.取表项数 (), i2)
    处理事件 ()
    .计次循环首 (取数组成员数 (Data_Head), i1)
      Excel工作簿1.首单元格 ＝ 字符 (97 ＋ i1 － 1) ＋ 到文本 (i2 ＋ 1)
      Excel工作簿1.尾单元格 ＝ 字符 (97 ＋ i1 － 1) ＋ 到文本 (i2 ＋ 1)
      Excel工作簿1.内容格式 ＝ “@”
      Excel工作簿1.内容 ＝ 超级列表框1.取标题 (i2 － 1, i1)
    .计次循环尾 ()
  .计次循环尾 ()
.如果真结束
.如果真 (全部 ＝ 假)
  .计次循环首 (超级列表框1.取表项数 (), i2)
    .如果真 (超级列表框1.取当前状态图片 (i2 － 1) ＝ 1)
      处理事件 ()
      .计次循环首 (取数组成员数 (Data_Head), i1)
        Excel工作簿1.首单元格 ＝ 字符 (97 ＋ i1 － 1) ＋ 到文本 (i2 ＋ 1)
        Excel工作簿1.尾单元格 ＝ 字符 (97 ＋ i1 － 1) ＋ 到文本 (i2 ＋ 1)
        Excel工作簿1.内容格式 ＝ “@”
        Excel工作簿1.内容 ＝ 超级列表框1.取标题 (i2 － 1, i1)
      .计次循环尾 ()
    .如果真结束
  .计次循环尾 ()
.如果真结束
Excel工作簿1.保存 (文件名)
Excel工作簿1.关闭 ()
Excel工作簿1.释放 ()
Excel程序1.退出 ()
Excel程序1.释放 ()
.子程序 __启动窗口_可否被关闭, 逻辑型
.局部变量 按钮, 整数型
按钮 ＝ 信息框 (“是否关闭软件”, #询问图标 ＋ #是否钮, )
.如果真 (按钮 ＝ #是钮)
  结束 ()
.如果真结束
返回 (假)